Imaginons que dans un script vous vouliez que les affichages sur la sortie standard (avec print par exemple),
soient récupérés, soit dans une variable, soit dans un autre script. Comment faire ?
Par exemple, vous voulez expérimenter un script CGI, mais vous n'avez pas de serveur Web, vous voulez juste voir l'affichage
renvoyé par le script REBOL cgi.
Ou bien juste débugger localement un script.
Cas numéro 1 :
Dans le cas où vous souhaitez récupérer le contenu de la sortie standard,
et le mettre ensuite dans une variable utilisable ,
vous pouvez utiliser le code
suivant de Dockimbel (
http://www.reboltech.com/library/html/capture.html)
Le code de DocKimbel, déclaré dans le contexte ctx-console-capture :
ctx-console-capture: context [
out: none
sys-print: get in system/words 'print
sys-prin: get in system/words 'prin
set 'get-captured does [out]
print-out: func [value][append out reform [reduce value newline]]
prin-out: func [value][append out reform value]
set 'capture func [flag [logic!]][
either flag [
out: make string! 1024
set 'print :print-out
set 'prin :prin-out
][
set 'print :sys-print
set 'prin :sys-prin
]
]
]
Le principe est le suivant :
Une fonction "capture" est activée par :
capture on
Dans ce cas, tout ce qui va sur la sortie standard avec prin ou print est ajouté (APPPEND) à une variable locale : out.
Pour arrêter la capture, il suffit d'un :
capture off
Le contenu capturé est finalement visible dans une variable globale : get-captured.
Il est ainsi possible localement d'activer cette fonction et de consulter après les informations.
Cas numéro 2 :
Ici, vous avez deux scripts.
Toutes les informations qui vont sur la sortie standard (stdout), via des PRINT ou PRIN, doivent être récupérées
un second script, et utilisées.
Bien qu'il y ait plusieurs manières de faire, en voici une qui utilise les redirections système.
Vous savez sans doute qu'il est possible de rediriger les entrées et sorties standard système (stdin, stdout).
Carl en parle par exemple dans son Blog (
http://www.rebol.net/article/0004.html).
Typiquement, créez un script en shell (suivant votre OS) qui contiendra le code suivant :
rebol.exe -wq code.r >infile.txt <outfile.txt
Les options de ligne de commande sont : -wq, c'est à dire : "tais-toi et n'ouvre pas de console".
Ici, le contenu de infile.txt va être passé en stdin (entrée standard) au script code.r,
et celui-ci va renvoyer sa sortie
standard (stdout) vers le fichier outfile.txt (recréé à chaque utilisation).
Exemple de fichier infile.txt :
print "HELLO WORLD"
blk: copy system/locale/months
foreach m blk [print m]
Ici, le fichier entier est passé au script code.r, qui va évaluer son contenu et
renvoyer tout vers stdout (c.à.d. outfile.txt).
Exemple de fichier code.r :
REBOL[]
print "DEBUT TEST"
set-modes system/ports/input [lines: false binary: false]
buffer: copy system/ports/input
do buffer
print "FIN TEST"
quit
Dans ce code, l'entrée standard (system/ports/input) est mise dans un buffer et celui-ci est évalué.
Les sorties (print "DEBUT TEST" par exemple) sont renvoyées vers le fichier outfile.txt.
Le contenu d'outfile.txt :
DEBUT TEST
HELLO WORLD
January
February
March
April
May
June
July
August
September
October
November
December
FIN TEST
Et en plus :
Il est possible aussi d'utiliser une redirection stdout depuis REBOL
system/ports/output: open/direct %log.txt
va renvoyer tous les affichages vers %log.txt
Egalement, l'usage de :
data: read console://
va ouvrir (via le scheme 'console) stdin en lecture. Tout ce qui est tapé dans la console est stocké dans la variable
data.
Un
break dans la console, suivi d'un
print data renvoie ce qui a été saisi.
Et voilà !
===Philippe
